diff -r 000000000000 -r f2cd752db494 bindings/Cocoa/MYOttoman.mm
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/bindings/Cocoa/MYOttoman.mm	Thu Sep 24 21:47:06 2009 -0700
@@ -0,0 +1,205 @@
+//
+//  MYOttoman.mm
+//  Ottoman
+//
+//  Created by Jens Alfke on 9/21/09.
+//  Copyright 2009 Jens Alfke. All rights reserved.
+//
+
+#import "MYOttoman.h"
+#import "MYOttoman_internal.h"
+extern "C" {
+#import "Test.h"
+}
+
+#include "Ottoman.h"
+#include "VersionDictionary.h"
+#include "File.h"
+
+
+@interface MYOttoman ()
+- (void) _versionsChanged;
+@end
+
+
+namespace Mooseyard {
+
+    class ObjCOwnedOttoman :public Ottoman {
+    public:
+        ObjCOwnedOttoman (MYOttoman *owner)
+        :_owner(owner)
+        { }
+        
+        ObjCOwnedOttoman (MYOttoman *owner, NSURL *fileURL, bool writeable)
+        :Ottoman(fileURL.path.fileSystemRepresentation, writeable),
+        _owner(owner)
+        { }
+        
+    protected:
+        virtual void versionsChanged() {
+            [_owner _versionsChanged];
+        }
+    private:
+        MYOttoman *_owner;
+    };
+    
+}
+
+
+using namespace Mooseyard;
+
+
+static BOOL ErrorToNSError (const File::Error &x, NSError **outError) {
+    if (outError) {
+        *outError = [NSError errorWithDomain: NSPOSIXErrorDomain
+                                        code: x.code
+                                    userInfo: nil];
+    }
+    return NO;
+}
+
+
+@interface MYOttoman ()
+@property (readonly) Ottoman* ottoman;
+@end
+
+
+@implementation MYOttoman
+
+
+- (id) init {
+    return [self initWithURL: nil writeable: YES error: nil];
+}
+
+- (id) initWithURL: (NSURL*)fileURL
+         writeable: (BOOL)writeable
+             error: (NSError**)outError
+{
+    self = [super init];
+    if (self) {
+        try {
+            if (fileURL) {
+                NSAssert([fileURL isFileURL], @"MYOttoman only supports file: URLs");
+                _ottoman = new ObjCOwnedOttoman(self, fileURL, writeable);
+            } else {
+                _ottoman = new ObjCOwnedOttoman(self);
+            }
+        } catch (const File::Error &x) {
+            ErrorToNSError(x,outError);
+            [self release];
+            return nil;
+        }
+        
+        if (writeable)
+            _currentVersion = [[MYCurrentVersionDictionary alloc]
+                                        _initWithOverlayDictionary: self.ottoman->currentVersion()];
+    }
+    return self;
+}
+
+- (void) dealloc
+{
+    [_lastVersion release];
+    [_currentVersion release];
+    delete (Ottoman*)_ottoman;
+    [super dealloc];
+}
+
+- (void) finalize {
+    delete (Ottoman*)_ottoman;
+    [super finalize];
+}
+
+- (void) close {
+    delete (Ottoman*)_ottoman;
+    _ottoman = nil;
+}
+
+
+- (Ottoman*) ottoman {
+    Assert(_ottoman, @"MYOttoman has already been closed");
+    return (Ottoman*) _ottoman;
+}
+
+- (NSURL*) URL {
+    const char *path = self.ottoman->filename();
+    return path ?[NSURL fileURLWithPath: [NSString stringWithUTF8String: path]] :nil;
+}
+
+
+- (MYVersionDictionary*) lastVersion {
+    if (!_lastVersion)
+        _lastVersion = [[MYVersionDictionary alloc] _initWithVersionDictionary: self.ottoman->lastVersion()];
+    return _lastVersion;
+}
+
+- (MYCurrentVersionDictionary*) currentVersion {
+    return _currentVersion;
+}
+
+- (void) _versionsChanged {
+    [_lastVersion autorelease];
+    _lastVersion = nil;
+}
+
+
+- (BOOL) needsSync {
+    return self.ottoman->needsSync();
+}
+
+
+- (BOOL) sync: (NSError**)outError {
+    if (outError) *outError = nil;
+    try {
+        return self.ottoman->sync();
+    } catch (const File::Error &x) {
+        return ErrorToNSError(x,outError);
+    }
+}
+
+- (BOOL) save: (NSError**)outError {
+    if (outError) *outError = nil;
+    try {
+        return self.ottoman->save();
+    } catch (const File::Error &x) {
+        return ErrorToNSError(x,outError);
+    }
+}
+
+- (BOOL) saveAndCompact: (NSError**)outError {
+    if (outError) *outError = nil;
+    try {
+        return self.ottoman->saveAndCompact();
+    } catch (const File::Error &x) {
+        return ErrorToNSError(x,outError);
+    }
+}
+
+- (BOOL) saveAs: (NSURL*)newFileURL
+         overwriteAllowed: (BOOL)overwriteAllowed
+         error: (NSError**)outError
+{
+    NSParameterAssert(newFileURL!=nil);
+    NSAssert([newFileURL isFileURL], @"MYOttoman only supports file: URLs");
+    if (outError) *outError = nil;
+    try {
+        self.ottoman->saveAs(newFileURL.path.fileSystemRepresentation, overwriteAllowed);
+        return YES;
+    } catch (const File::Error &x) {
+        return ErrorToNSError(x,outError);
+    }
+}
+
+
+- (BOOL) scavengeAndRepair: (BOOL)repair error: (NSError**)outError {
+    if (outError) *outError = nil;
+    try {
+        return self.ottoman->scavenge(repair);
+    } catch (const File::Error &x) {
+        return ErrorToNSError(x,outError);
+    }
+}
+
+
+@end
+