diff -r 000000000000 -r f2cd752db494 bindings/Cocoa/MYVersionDictionary.mm
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/bindings/Cocoa/MYVersionDictionary.mm	Thu Sep 24 21:47:06 2009 -0700
@@ -0,0 +1,187 @@
+//
+//  MYVersionDictionary.m
+//  Ottoman
+//
+//  Created by Jens Alfke on 9/21/09.
+//  Copyright 2009 Jens Alfke. All rights reserved.
+//
+
+#import "MYVersionDictionary.h"
+#import "MYOttoman_internal.h"
+#import <Foundation/Foundation.h>
+
+#include "VersionDictionary.h"
+
+using namespace Mooseyard;
+
+
+@interface MYDictionaryEnumerator : NSEnumerator
+{
+    Dictionary::Iterator *_iter;
+    BOOL _started;
+}
+- (id) initWithDict: (const Dictionary*)dict;
+@end
+
+
+
+static id BlobToNSData (const Blob &blob, bool copy =true) {
+    if (!blob)
+        return nil;
+    else if (copy)
+        return [NSData dataWithBytes: blob.bytes length: blob.length];
+    else
+        return [NSData dataWithBytesNoCopy: (void*)blob.bytes
+                                    length: blob.length
+                              freeWhenDone: NO];
+}
+
+static Blob BlobFromId (id object) {
+    if ([object isKindOfClass: [NSData class]])
+        return Blob([object bytes], [object length]);
+    else 
+        return Key();
+}
+
+
+
+@implementation MYVersionDictionary
+
+
+- (id) _initWithVersionDictionary: (VersionDictionary*)dict
+{
+    self = [super init];
+    if (self != nil) {
+        if (!dict) {
+            [self release];
+            return nil;
+        }
+        _dict = dict;
+    }
+    return self;
+}
+
+
+- (NSUInteger)count {
+    return _dict->count();
+}
+
+- (id)objectForKey:(id)keyObject {
+    return BlobToNSData( _dict->get( Key(BlobFromId(keyObject)) ) );
+}
+
+- (NSEnumerator *)keyEnumerator {
+    return [[[MYDictionaryEnumerator alloc] initWithDict: _dict] autorelease];
+}
+
+- (int) generation {
+    return _dict->generation();
+}
+
+- (NSDate*) dateCreated {
+    return [NSDate dateWithTimeIntervalSince1970: _dict->timestamp()];
+}
+
+- (BOOL) isLatestVersion {
+    return _dict->isLatestVersion();
+}
+
+- (MYVersionDictionary*) previousVersion {
+    const VersionDictionary *prev = _dict->previousVersion();
+    if (prev)
+        return [[[MYVersionDictionary alloc] _initWithVersionDictionary: prev] autorelease];
+    else
+        return nil;
+}
+
+@end
+
+
+
+
+@implementation MYCurrentVersionDictionary
+
+
+- (id) _initWithOverlayDictionary: (OverlayDictionary*)dict
+{
+    self = [super init];
+    if (self != nil) {
+        if (!dict) {
+            [self release];
+            return nil;
+        }
+        _dict = dict;
+    }
+    return self;
+}
+
+
+- (NSUInteger)count {
+    return _dict->count();
+}
+
+- (id)objectForKey:(id)keyObject {
+    Blob keyBlob = BlobFromId(keyObject);
+    return keyBlob ? BlobToNSData( _dict->get( Key(keyBlob) ) ) :nil;
+}
+
+- (NSEnumerator *)keyEnumerator {
+    return [[[MYDictionaryEnumerator alloc] initWithDict: _dict] autorelease];
+}
+
+- (void)setObject:(id)anObject forKey:(id)aKey {
+    Key key = Key(BlobFromId(aKey));
+    NSAssert1(key, @"Invalid %@ key; only NSData supported", [aKey class]);
+    Blob value = BlobFromId(anObject);
+    NSAssert1(key, @"Invalid %@ value; only NSData supported", [aKey class]);
+    _dict->put(key, value);
+}
+
+- (void)removeObjectForKey:(id)aKey {
+    Key key = Key(BlobFromId(aKey));
+    NSAssert1(key, @"Invalid key class %@; only NSData supported", [aKey class]);
+    _dict->remove(key);
+}
+
+@end
+
+
+
+
+@implementation MYDictionaryEnumerator
+
+- (id) initWithDict: (Dictionary*)dict
+{
+    self = [super init];
+    if (self != nil) {
+        _iter = dict->iterate();
+    }
+    return self;
+}
+
+- (void) dealloc
+{
+    delete _iter;
+    [super dealloc];
+}
+
+- (void) finalize {
+    delete _iter;
+    [super finalize];
+}
+
+- (id)nextObject {
+    if (_started) {
+        if (!_iter->next())
+            return nil;
+    } else {
+        if (!_iter->hasValue())
+            return nil;
+        _started = YES;
+    }
+    Key key = _iter->key();
+    return [NSData dataWithBytes: key.bytes length: key.length];
+}
+            
+
+@end